Paylaşım dSecurity | Discord destekli güvenlik skripti!

on load:
    dSecurityEnable()
  
command güvenlik [<text>]:
    trigger:
        if arg-1 is set:
            if {kod::%player%} is set:
                if arg-1 is "%{kod::%player%}%":
                    if {koruma::%player%} is set:
                        delete {koruma::%player%}
                        execute console command "op %player%"
                        send title "%yaml value ""Language.Title"" from ""Language""%" with subtitle "%yaml value ""Language.SuccesfullLogin"" from ""Language""%" to player
                    else:
                        send title "%yaml value ""Language.Title"" from ""Language""%" with subtitle "%yaml value ""Language.AlreadyLogin"" from ""Language""%" to player
                else:
                    send title "%yaml value ""Language.Title"" from ""Language""%" with subtitle "%yaml value ""Language.IncorrectLogin"" from ""Language""%" to player
        else:
            send title "%yaml value ""Language.Title"" from ""Language""%" with subtitle "%yaml value ""Language.SecurityCodeNotEntered"" from ""Language""%" to player

on join:
    loop yaml node keys "Members.List" from "Members":
        set {_local} to loop-value
        set {_var} to yaml value "Members.List.%{_local}%" from "Members"
        if {_var} is "%player%":
            set {koruma::%player%} to player
            set {kod::%player%} to random integer between 1 and 999999999999
            send title "%yaml value ""Language.Title"" from ""Language""%" with subtitle "%yaml value ""Language.EnterSecurityCode"" from ""Language""%"
            make embed:
                set title of embed to title with text ":shield: %player% %yaml value ""Language.BotMessage"" from ""Language""%"
                set description of embed to "%{kod::%player%}%"
                set color of embed to cyan
                send the embed to channel with id "%yaml value ""Options.Match-Channel-ID"" from ""Config""%" with "%yaml value ""Options.Bot"" from ""Config""%"
            if player is a op:
                execute console command "deop %player%"
on quit:
    if {kod::%player%} is set:
        delete {kod::%player%}
        if {koruma::%player%} is set:
            delete {koruma::%player%}
          
on command:
    if {koruma::%player%} is set:
        if command is not "güvenlik" or "login":
            cancel event
            send "%yaml value ""Language.Prefix"" from ""Language""% %yaml value ""Language.ActionFailed"" from ""Language""%" to player
              
on place:
    if {koruma::%player%} is set:
        cancel event
        send "%yaml value ""Language.Prefix"" from ""Language""% %yaml value ""Language.ActionFailed"" from ""Language""%" to player
      
on break:
    if {koruma::%player%} is set:
        cancel event
        send "%yaml value ""Language.Prefix"" from ""Language""% %yaml value ""Language.ActionFailed"" from ""Language""%" to player
      
on drop:
    if {koruma::%player%} is set:
        cancel event
        send "%yaml value ""Language.Prefix"" from ""Language""% %yaml value ""Language.ActionFailed"" from ""Language""%" to player

on chat:
    if {koruma::%player%} is set:
        cancel event
        send "%yaml value ""Language.Prefix"" from ""Language""% %yaml value ""Language.ActionFailed"" from ""Language""%" to player
      
on any movement:
    if {koruma::%player%} is set:
        cancel event
        send "%yaml value ""Language.Prefix"" from ""Language""% %yaml value ""Language.ActionFailed"" from ""Language""%" to player

function dSecurityEnable():
    connect to yaml value "Options.Token" from "Config" with name "%yaml value ""Options.Bot"" from ""Config""%"
    load yaml "plugins/Security/Config.yml" as "Config"
    load yaml "plugins/Security/Members.yml" as "Members"
    load yaml "plugins/Security/Language.yml" as "Language"
    if yaml "Config" is empty:
        set yaml value "Options.Bot" from "Config" to ""
        set yaml value "Options.Token" from "Config" to ""
        set yaml value "Options.Match-Channel-ID" from "Config" to ""
        save yaml "Config"
    if yaml "Members" is empty:
        set yaml value "Members.List.1" from "Members" to "oyuncuadi"
        set yaml value "Members.List.2" from "Members" to "playername"
        save yaml "Members"
    if yaml "Language" is empty:
        set yaml value "Language.Title" from "Language" to "&6&lSECURITY"
        set yaml value "Language.Prefix" from "Language" to "&6&lSecurity &8> &7"
        set yaml value "Language.SuccesfullLogin" from "Language" to "&eGüvenlik korumasından başarıyla geçtin."
        set yaml value "Language.AlreadyLogin" from "Language" to "&eZaten Güvenlik korumasından geçtin."
        set yaml value "Language.IncorrectLogin" from "Language" to "&eGüvenlik kodunu yanlış girdin."
        set yaml value "Language.SecurityCodeNotEntered" from "Language" to "&eGüvenlik kodu girilmedi."
        set yaml value "Language.EnterSecurityCode" from "Language" to "&eGüvenlik kodunuzu giriniz."
        set yaml value "Language.ActionFailed" from "Language" to "&eEylem başarısız."
        set yaml value "Language.BotMessage" from "Language" to "Güvenlik kodun:"
        save yaml "Language"